HaskellでDIする

設計を定義するときには他の言語ではインターフェイスなどの仕組みが使われることが多い。 Haskellには型システムという仕組みがあるのでこれがインターフェイス相当の機能として紹介される場合がある。

しかし型システムはインターフェイスとは違い、型を固定する仕組みがない。型クラス TypeClass a のインスタンスの値が x:TypeClass a => a と y:TypeClass a => a のように2つ与えられたとしても、xとyが同じ型である保証はないし、これが同じ型であることを強制するためにはxとyを同時に作って常に同時に運ぶ必要がある。

というわけでインターフェイスを使うと型が固定できないのでDIしようとすると困ったことになる、と私はずっと思っていた。

型を固定する仕組みは実はどうにかすることができて、要は存在型を使って data Trapped = forall a. TypeClass a => Trapped a とやると型を外から見えないように隠蔽することができる。

存在型は中を開いたときにもともと何が入っていたかはわからなくなるが、設計ではそれを意識する必要がないはずなので特に問題がない。

さらに、いわゆるDIコンテナ的な仕組みでは生成したオブジェクトを必要なところに注入してくれるという機能があることが多いが、実はこれと同じこともHaskellではできる。

reflectionというパッケージがあり、これはconfigデータを外から与えるためによく使用される。 Given a => ... なる型をもつプログラムは given と書くといつでも好きなタイミングで外から挿入されたaの値を取り出すことができる。

同じ型に対しては1つの値しか注入できないが、実際にDIするときは利用する型は1つだけなので問題がない。

というわけでこれでHaskellでもDIできそう！ということが分かる。

  class Logger a where
    writeLog :: a -> String -> IO ()

ロガーは文字列を受け取って何かするというインターフェイスを実装した型のことであろう。ここでの a に、具体的なLogger型が挿入される。

  data SomeLogger = forall a. Logger a => SomeLogger a

  instance Logger SomeLogger where
    writeLog (SomeLogger i) = writeLog i

先程も説明したとおりに SomeLogger という型を用意しておく。SomeLoggerはロガーのinstanceが閉じ込められている。 また、SomeLoggerは自明にLoggerとしての機能を与えることができるのでそれも与えておく。

  type UseLogger = Given SomeLogger

  useLogger :: UseLogger => SomeLogger
  useLogger = given

reflectionのAPIを専用関数としてラップしたものを用意しておく。この辺は好み(巷のDIコンテナのノリに合わせた)。

実装をエイヤって与える。

  data StdoutLoggerImpl = StdoutLoggerImpl

  instance Logger StdoutLoggerImpl where
    writeLog _ str = putStrLn str

  newLogger :: SomeLogger
  newLogger = SomeLogger StdoutLoggerImpl

せやなという感じ。

ロガーを使いたいときは次のようにすれば良い。

  something :: UseLogger => ...
  something = do
    writeLog useLogger "write to log!"

UseLogger => の中では useLogger を使うことができてロガーを使うことができる。ここではロガーの具体的な型には言及しなくてもよいところが大事。

注入したいときは give StdoutLoggerImpl.newLogger $ ... ってやる。

アプリケーションの一番外側のレイヤーでやればよい。